XFEServerManager

plugins {
    id 'java'
    id 'idea'
    id 'eclipse'
    id 'net.minecraftforge.gradle' version '7.0.36'
    id 'net.minecraftforge.jarjar' version '0.2.3'
}

apply from: rootProject.file('../shared/forge-common.gradle')

configurations {
    xfesmRuntimeLibrary
    implementation.extendsFrom(xfesmRuntimeLibrary)
}

jarJar.register() {
    archiveClassifier = null
}

tasks.named('jar', Jar).configure {
    archiveClassifier = 'slim'
}

minecraft {
    mappings channel: 'official', version: minecraft_version

    runs {
        configureEach {
            workingDir = layout.projectDirectory.dir('run')
            systemProperty 'forge.enabledGameTestNamespaces', mod_id
            extraLibraries project.configurations.xfesmRuntimeLibrary
        }
        register('server') {
            args '--nogui', '--mixin', 'xfeservermanager.mixins.json'
        }
        register('gameTestServer')
    }
}

repositories {
    minecraft.mavenizer(it)
    maven fg.forgeMaven
    maven fg.minecraftLibsMaven
    mavenCentral()
}

dependencies {
    implementation minecraft.dependency("net.minecraftforge:forge:${minecraft_version}-${forge_version}")
    xfesmRuntimeLibrary 'org.xerial:sqlite-jdbc:3.53.1.0'
    xfesmRuntimeLibrary 'org.bouncycastle:bcprov-jdk18on:1.84'
    def sqliteJarJar = jarJar('org.xerial:sqlite-jdbc:3.53.1.0') { transitive = false }
    def bcprovJarJar = jarJar('org.bouncycastle:bcprov-jdk18on:1.84') { transitive = false }
    jarJar.configure(sqliteJarJar) {
        range = '[3.53.1.0,3.54)'
        version = '3.53.1.0'
    }
    jarJar.configure(bcprovJarJar) {
        range = '[1.84,1.85)'
        version = '1.84'
    }
}

tasks.named('assemble').configure {
    dependsOn 'jarJar'
}